Hallo,

ist ja interessant, dass der Safari-Browser ebenfalls seinen eigenen "Web-Standard" definiert hat. Für den iPad kann man ach einen Firefox installieren: https://www.mozilla.org/de/firefox/ios/ Dann sollten auch die Inhalte korrekt übertragen werden.

Wenn die Werte in Spalte C überschrieben werden sollen, kann folgender VBA-Code verwendet werden:

Sub HyperlinkEinfügen()
    Dim rngC As Range
    Dim strC As String
    Dim iRow As Integer
    Dim hyp As Hyperlink
    With ActiveSheet
        For iRow = 1 To .UsedRange.Rows.Count
            Set rngC = .Cells(iRow, 3)
            If rngC.Value <> "" Then
                If rngC.Hyperlinks.Count = 0 Then
                    strC = rngC.Value
                    Set hyp = .Hyperlinks.Add(anchor:=rngC, Address:="http://www.google.de/#hl=de&output=search&sclient=psy-ab&q=" & WorksheetFunction.EncodeURL(strC))
                    hyp.TextToDisplay = "Google-Suche"
                End If
            End If
        Next
    End With
End Sub

Hinweis: Beim erneuten Aufruf wird eine bestehender Hyperlink nicht verändert werden.

Falls der Ersetzungs-Vorgang für die Inhalte der Spalte C direkt nach dem Ändern eines Inhalts automatisiert durchgeführt werden sollen, kann auch folgender VBA-Code eingesetzt werden:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngC As Range
    Dim strC As String
    Dim iRow As Integer
    Dim hyp As Hyperlink
    With ActiveSheet
        Set rngC = Target.Worksheet.Range("C:C")
        If Not Intersect(rngC, Target) Is Nothing Then
            If Target.Value <> "" Then
                If Target.Hyperlinks.Count = 0 Then
                    strC = Target.Value
                    Application.EnableEvents = False
                    Set hyp = .Hyperlinks.Add(anchor:=Target, Address:="http://www.google.de/#hl=de&output=search&sclient=psy-ab&q=" & WorksheetFunction.EncodeURL(strC))
                    hyp.TextToDisplay = "Google-Suche"
                    Application.EnableEvents = True
                End If
            End If
        End If
    End With
End Sub

Dieser VBA-Code muss direkt in das Tabellen-Objekt im VBA-Editor eingefügt werden.

Eine Beispiel-Arbeitsmappe kann auch hier heruntergeladen werden.

LG, BigBen