Man sollte dabei immer im Kopf behalten, dass dies alles asynchron abläuft.

Den nächsten Durchgang also erst lostreten, wenn der vorherige abgeschlossen ist. Dieses Application.Wait ist da nicht für geeignet.

'
'Ort: in einem beliebigen Klassenmodul (z.B. Tabelle1)
'
'erforderliche Verweise: (VBA-Editor Menü: 'Extras' -> 'Verweise...')
' * Microsoft Internet Controls
' * Microsoft HTML Objekt Library
'
'Anmerkung:
' Sämtliche Ausgaben erfolgen in diesem Beispiel im Direktfenster
' (ggf. einblenden über VBA-Editor Menü: 'Ansicht' -> 'Direktfenster').
Option Explicit

Private WithEvents MyWebBrowser As SHDocVw.InternetExplorer
Private vntaURL As Variant
Private URLIdx As Long

Sub Testlauf_Start()
  
  vntaURL = Array("www.google.de", "www.bing.de", "www.yahoo.de")
  URLIdx = LBound(vntaURL)
  
  If MyWebBrowser Is Nothing Then
    Set MyWebBrowser = New SHDocVw.InternetExplorer
  End If
  
  Call MyWebBrowser.Navigate(vntaURL(URLIdx))
  
End Sub

Private Sub MyWebBrowser_DocumentComplete(ByVal pDisp As Object, URL As Variant)
  
  Dim htmlDoc   As MSHTML.HTMLDocument
  Dim htmlLinks As MSHTML.IHTMLElementCollection
  Dim i         As Long
  
  Set htmlDoc = MyWebBrowser.document
  Set htmlLinks = htmlDoc.getElementsByTagName("a")

'>> Ausgabe im Direktfenster >>
  Debug.Print 'leere Zeile
  Debug.Print "URLIdx[" & URLIdx & "] = '" & vntaURL(URLIdx) & "'"
  'maximal drei Links dieser Seite ausgeben
  For i = 0 To WorksheetFunction.Min(3, htmlLinks.Length) - 1
    Debug.Print Tab(5); "Link" & (1 + i) & " = '" & htmlLinks(i).href & "'"
  Next
  If htmlLinks.Length > 0 Then
    Debug.Print Tab(5); "..."
    Debug.Print Tab(5); "(Links insgesamt: " & htmlLinks.Length & ")"
  Else
    Debug.Print Tab(5); "(keine Links vorhanden)"
  End If
'<< Ausgabe im Direktfenster <<

  If URLIdx < UBound(vntaURL) Then
  '> nächste URL
    URLIdx = URLIdx + 1
    Call MyWebBrowser.Navigate(vntaURL(URLIdx))
  Else
  '> keine URL mehr verfügbar -> Objekt freigeben
    Call MyWebBrowser.Quit
    Set MyWebBrowser = Nothing '(!)
  End If
  
End Sub