Thema Datum  Von Nutzer Rating
Antwort
07.05.2014 17:17:55 Pbrue
NotSolved
07.05.2014 17:45:47 Gast65084
NotSolved
09.05.2014 22:36:39 Philipp
NotSolved
Blau Mehrere XML-Dateien in mehrere Excel-Dateien umwandeln
 09.05.2014 23:17:04 Gast42426
NotSolved
09.05.2014 23:20:36 Gast98454
NotSolved
09.05.2014 23:24:17 Gast54713
NotSolved
09.05.2014 23:30:48 Gast63562
NotSolved

Ansicht des Beitrags:
Von:
Gast42426		 Datum:
09.05.2014 23:17:04		 Views:
847		 Rating:
     
Antwort:
  Ja
Thema:
Mehrere XML-Dateien in mehrere Excel-Dateien umwandeln		 
Option Explicit

Sub AlleLesen()
  
  Const cstrOutPath As String = "C:\Neuer Ordner\"
  Const cstrInpPath As String = cstrOutPath & "XMLs\"
  
  On Error GoTo ErrHandler
  
  Dim strName As String
  Dim strNewName As String
  
  Application.ScreenUpdating = False
  Application.DisplayAlerts = False
  
  strName = Dir$(cstrInpPath & "*.xml")
  While strName <> ""
    
    Application.StatusBar = "Bearbeite: " & strName
    
    'die Dateiendung wird später automatisch ergänzt
    strNewName = Replace(strName, ".xml", "", Compare:=vbTextCompare, Count:=1)
    
    With Workbooks.Add()
      
      While .Worksheets.Count > 1
        .Worksheets(.Worksheets.Count).Delete
      Wend
      
      Select Case .XmlImport(cstrInpPath & strName, ImportMap:=Nothing, _
                            Destination:=.Worksheets(1).Range("A1"), _
                            Overwrite:=True)
        Case xlXmlImportSuccess, xlXmlImportElementsTruncated
          Call .SaveAs(cstrOutPath & strNewName, .FileFormat)
      End Select
      
      Call .Close(SaveChanges:=False)
      
    End With
    
    strName = Dir$()
  Wend
  
SafeExit:
  Application.StatusBar = False
  Application.DisplayAlerts = True
  Application.ScreenUpdating = True
  Exit Sub
  
ErrHandler:
  Call MsgBox(Err.Description, vbCritical, "Fehler " & Err.Number)
  GoTo SafeExit
End Sub

 

Ihre Antwort
  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen
Thema: Name: Email:



  • Bitte beschreiben Sie Ihr Problem möglichst ausführlich. (Wichtige Info z.B.: Office Version, Betriebssystem, Wo genau kommen Sie nicht weiter)
  • Bitte helfen Sie ebenfalls wenn Ihnen geholfen werden konnte und markieren Sie Ihre Anfrage als erledigt (Klick auf Häckchen)
  • Bei Crossposting, entsprechende Links auf andere Forenbeiträge beifügen / nachtragen
  • Codeschnipsel am besten über den Code-Button im Text-Editor einfügen
  • Die Angabe der Emailadresse ist freiwillig und wird nur verwendet, um Sie bei Antworten auf Ihren Beitrag zu benachrichtigen

Thema Datum  Von Nutzer Rating
Antwort
07.05.2014 17:17:55 Pbrue
NotSolved
07.05.2014 17:45:47 Gast65084
NotSolved
09.05.2014 22:36:39 Philipp
NotSolved
Blau Mehrere XML-Dateien in mehrere Excel-Dateien umwandeln
 09.05.2014 23:17:04 Gast42426
NotSolved
09.05.2014 23:20:36 Gast98454
NotSolved
09.05.2014 23:24:17 Gast54713
NotSolved
09.05.2014 23:30:48 Gast63562
NotSolved