Option Explicit

Sub blaa()
  
  Dim rngBereich As Excel.Range
  Dim rngZeile As Excel.Range
  Dim rngZelle As Excel.Range
  Dim tmp As String
  
  With Tabelle1
    
    'AutoFilter aktiv?
    If .AutoFilterMode Then
    '... ja, ist aktiv.
      
      'Bereich des AutoFilters
      Set rngBereich = .AutoFilter.Range
      'Kopfzeile (hier 1 Zeile groß) ausschließen
      Set rngBereich = rngBereich.Offset(RowOffset:=1).Resize(RowSize:=rngBereich.Rows.Count - 1)
      'und nun nur die sichtbaren Zellen berücksichtigen
      On Error Resume Next
      Set rngBereich = rngBereich.SpecialCells(xlCellTypeVisible)
      If Err.Number <> 0 Then Set rngBereich = Nothing
      On Error GoTo 0
      
      'Haben wir was zum Anzeigen?
      If Not rngBereich Is Nothing Then
      '... ja, haben wir.
        
        For Each rngZeile In rngBereich.Rows
          
          'nur bestimmte Spalten berücksichtigen (hier im Beispiel: Spalte A und C)
          Set rngZeile = Intersect(rngZeile, Union(.Columns("A"), .Columns("C")))
          
          'Haben wir jetzt immernoch was zum Anzeigen?
          If Not rngZeile Is Nothing Then
          '... ja, haben wir.
            
            'Zeile zusammenfassen, mit Tabulator als Trennzeichen
            tmp = ""
            For Each rngZelle In rngZeile.Cells
              tmp = tmp & IIf(tmp <> "", vbTab, "") & rngZelle.Text
            Next
            
            'simple Ausgabe auf Bildschirm
            MsgBox tmp
            
          End If
          
        Next rngZeile
        
      End If
      
    Else
      MsgBox "Auto-Filter ist nicht aktiv.", vbExclamation
      Exit Sub
    End If
    
  End With
  
  If rngBereich Is Nothing Then
    MsgBox "Keine Daten zu verarbeiten.", vbInformation
  Else
    MsgBox "Daten wurden verarbeitet.", vbInformation
  End If
  
End Sub

PS: Schau dir bitte mal in der VBA-Hilfe FreeFile an. Man sollte nicht davon ausgehen, dass der Wert 1 (s. Open-Statement) immer funktioniert.